'# Windows disk usage monitorization plugin for Pandora FMS agent
'# Author: Manuel A. Gulín Bejarano
'# Version: 1.0
'# Date: 22/04/2013
'#
'# This program is free software: you can redistribute it and/or modify
'#  it under the terms of the GNU General Public License as published by
'#  the Free Software Foundation, either version 3 of the License, or
'#  (at your option) any later version.
'#
'# This program is distributed in the hope that it will be useful,
'#  but WITHOUT ANY WARRANTY; without even the implied warranty of
'#  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
'#  GNU General Public License for more details.
'#
'# You should have received a copy of the GNU General Public License
'#  along with this program.  If not, see <http://www.gnu.org/licenses/>.
'#
'#
'# Load with:
'#	module_plugin cscript.exe //B "%ProgramFiles%\pandora_agent\util\diskusage_plugin.vbs"


Option Explicit
On Error Resume Next

' Variables
Dim objWMIService, objItem, colItems, argc, argv, i, Percent

' Parse command line parameters
argc = Wscript.Arguments.Count
Set argv = CreateObject("Scripting.Dictionary")
For i = 0 To argc - 1
    argv.Add Wscript.Arguments(i), i
Next

' Get drive information
Set objWMIService = GetObject ("winmgmts:\\.\root\cimv2")
Set colItems = objWMIService.ExecQuery ("Select * from Win32_LogicalDisk")

For Each objItem in colItems
	If argc = 0 Or argv.Exists(objItem.Name) Then
		' Include only harddrivers (type 3)
		If (objItem.FreeSpace <> "") AND (objItem.DriveType =3) Then
			'# Module to get the total size of a disk in megabytes
			Wscript.StdOut.WriteLine "<module>"
			Wscript.StdOut.WriteLine "    <name><![CDATA[Disk: Total space on " & objItem.Name & " (MB)]]></name>"
			Wscript.StdOut.WriteLine "    <description><![CDATA[Total space on " & objItem.Name & " (MB)]]></description>"
			Wscript.StdOut.WriteLine "    <type>generic_data</type>"
			Wscript.StdOut.WriteLine "    <unit>MB</unit>"
			Wscript.StdOut.WriteLine "    <disabled>0</disabled>"
			Wscript.StdOut.WriteLine "    <data><![CDATA[" & Int(objItem.Size /1048576) & "]]></data>"
			Wscript.StdOut.WriteLine "</module>"
            Wscript.StdOut.flush

			'# Module to get the used size of a disk in megabytes
			Wscript.StdOut.WriteLine "<module>"
			Wscript.StdOut.WriteLine "    <name><![CDATA[Disk: Used space on " & objItem.Name & " (MB)]]></name>"
			Wscript.StdOut.WriteLine "    <description><![CDATA[Used space on " & objItem.Name & " (MB)]]></description>"
			Wscript.StdOut.WriteLine "    <type>generic_data</type>"
			Wscript.StdOut.WriteLine "    <unit>MB</unit>"
			Wscript.StdOut.WriteLine "    <disabled>0</disabled>"
			Wscript.StdOut.WriteLine "    <data><![CDATA[" & (Int (objItem.Size) - Int(objItem.FreeSpace))/1048576 & "]]></data>"
			Wscript.StdOut.WriteLine "</module>"
            Wscript.StdOut.flush

			'# Module to get the percentage of size used
		        Percent = round (100 - (objItem.FreeSpace / objItem.Size) * 100, 2)
			Wscript.StdOut.WriteLine "<module>"
			Wscript.StdOut.WriteLine "    <name><![CDATA[Disk: Used space on " & objItem.Name & " (%)]]></name>"
			Wscript.StdOut.WriteLine "    <description><![CDATA[Used space on " & objItem.Name & " (%)]]></description>"
			Wscript.StdOut.WriteLine "    <type>generic_data</type>"
			Wscript.StdOut.WriteLine "    <unit>MB</unit>"
			Wscript.StdOut.WriteLine "    <min_warning>85</min_warning>"
			Wscript.StdOut.WriteLine "    <max_warning>89.9</max_warning>"
			Wscript.StdOut.WriteLine "    <min_critical>90</min_critical>"
			Wscript.StdOut.WriteLine "    <max_critical>100</max_critical>"
			Wscript.StdOut.WriteLine "    <disabled>0</disabled>"
			Wscript.StdOut.WriteLine "    <data><![CDATA[" & Percent & "]]></data>"
			Wscript.StdOut.WriteLine "</module>"
            Wscript.StdOut.flush
		End If
	End If
Next